Example queries

All the queries suppose this set of prefixes:

    PREFIX mus: <http://data.doremus.org/ontology#>
    PREFIX ecrm: <http://erlangen-crm.org/current/>
    PREFIX efrbroo: <http://erlangen-crm.org/efrbroo/>
    PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
    PREFIX foaf: <http://xmlns.com/foaf/0.1/>
    PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
    PREFIX time: <http://www.w3.org/2006/time#>
    PREFIX geonames: <http://www.geonames.org/ontology#>
    PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

#1: Work listing

Which works have been composed by Mozart? - results

SELECT DISTINCT ?expression ?title
WHERE {
  ?expression a efrbroo:F22_Self-Contained_Expression ;
          rdfs:label ?title .
  ?expCreation efrbroo:R17_created ?expression ;
          ecrm:P9_consists_of / ecrm:P14_carried_out_by ?composer .
  ?composer foaf:name "Wolfgang Amadeus Mozart"
} ORDER BY ?title

Which symphonies have been composed in 19th century? - results

SELECT DISTINCT ?expression ?title ?composerName ?date
WHERE {
  ?expression a efrbroo:F22_Self-Contained_Expression ;
          rdfs:label ?title ;
          mus:U12_has_genre / skos:exactMatch* <http://data.doremus.org/vocabulary/iaml/genre/sy> .

  ?expCreation efrbroo:R17_created ?expression ;
          ecrm:P4_has_time-span / time:hasBeginning / time:inXSDDate ?date ;
          ecrm:P9_consists_of / ecrm:P14_carried_out_by ?composer .
  ?composer foaf:name ?composerName

  FILTER (?date >= "1800-01-01"^^xsd:date && ?date < "1900-01-01"^^xsd:date)
} ORDER BY ?date

#2: Work detail

Retrieve all the information about Beethoven’s Sonata for Cello and Piano - results

SELECT DISTINCT *
WHERE {
    VALUES ?expression { <http://data.doremus.org/expression/614925f2-1da7-39c1-8fb7-4866b1d39fc7> }
    ?expression a efrbroo:F22_Self-Contained_Expression ;
            rdfs:label ?title .
    OPTIONAL{?expression ecrm:P3_has_note ?note .}
    OPTIONAL {
      ?expression mus:U13_has_casting / mus:U23_has_casting_detail / mus:U2_foresees_use_of_medium_of_performance ?mop .
    }
    OPTIONAL{
      ?expression mus:U12_has_genre ?genre .
    }
    OPTIONAL{?expression mus:U17_has_opus_statement / ecrm:P3_has_note ?opus}
    OPTIONAL{?expression mus:U10_has_order_number ?order .}
    OPTIONAL{?expression mus:U11_has_key ?key . }
    OPTIONAL{?expression mus:U16_has_catalogue_statement / rdfs:label ?catalogue }
    OPTIONAL{
      ?expCreation efrbroo:R17_created ?expression .
      OPTIONAL {
        ?expCreation ecrm:P9_consists_of ?activity ;
                     ecrm:P4_has_time-span / time:hasBeginning / time:inXSDDate ?creationStart .
        ?activity ecrm:P14_carried_out_by ?composerUri ;
                  mus:U31_had_function <http://data.doremus.org/vocabulary/function/composer> .
      }
    }
}

#3: Artist listing

List all composers - results

SELECT DISTINCT ?artist ?name
WHERE {
    [] mus:U31_had_function <http://data.doremus.org/vocabulary/function/composer> ;
        ecrm:P14_carried_out_by ?artist .
    ?artist foaf:name ?name
}

List all performers - results

SELECT DISTINCT ?artist ?name
WHERE {
    [] a mus:M28_Individual_Performance ;
        ecrm:P14_carried_out_by ?artist .
    ?artist foaf:name ?name
}

List all singers - results

SELECT DISTINCT ?artist ?name ?mop
WHERE {
    [] a mus:M28_Individual_Performance ;
        mus:U1_used_medium_of_performance ?mop ;
        ecrm:P14_carried_out_by ?artist .
    ?artist foaf:name ?name .
    ?mop skos:broader <http://data.doremus.org/vocabulary/iaml/mop/v>
}

#4: Performances

List all performance of Bizet's Carmen - results

SELECT DISTINCT *
    WHERE {
        ?performance efrbroo:R66_included_performed_version_of <http://data.doremus.org/expression/4d4fed5f-e383-3560-9aa3-bf6496e1c335> .

        OPTIONAL { ?performance ecrm:P4_has_time-span / time:hasBeginning / time:inXSDDate ?time }
        OPTIONAL { ?performance ecrm:P7_took_place_at / (rdfs:label | geonames:name) ?place }
        OPTIONAL { ?performance ecrm:P3_has_note ?note }

     }

List all the concerts at Maison de la Radio - results

SELECT DISTINCT *
    WHERE {
        ?performance a efrbroo:F31_Performance ;
                ecrm:P7_took_place_at <http://data.doremus.org/place/687896c9-0db7-31cf-8b20-5fa73dc268d6>
    }

#5: Foreseen Events

List all the performances forseen at the Philharmonie de Paris on January 2017 - results

SELECT DISTINCT *
WHERE {
  ?event a mus:M26_Foreseen_Performance ;
         rdfs:label ?title ;
         mus:U7_foresees_place_at <http://data.doremus.org/place/bd21be9c-3f2b-3aa3-a460-114d579eabe6> ;
         mus:U8_foresees_time_span / time:hasBeginning / time:inXSDDate ?date .
  FILTER(year(?date) = 2017)
} ORDER BY ?date